# Theorems for non-covariant transverse photon polarization vectors

photon1.wxmx,    Nov. 6, 2018
 Edwin (Ted) Woollett,   Maxima by Example Ch. 12,
Dirac Algebra and Quantum Electrodynamics, ver. 3, "Dirac3"
http://web.csulb.edu/~woollett/
----------------------------------------------------------

Two theorems satisfied by the real linear polarixation vectors of
a physical massless photon.

Consider a scattered photon k_vec -->  kp_vec.

 Assume the  scattering plane is z-x plane.
 
k_vec is directed along the +z axis and has magnitude k.

kp_vec lies in the z-x plane and has magnitude kp (think "k-prime").

In general, we define 3-vectors as lists, say  L1 and L2.

Then the dot product (scalar product)  is produced via

   L1 . L2

The usual vector cross product is returned as a list
using the dirac3 package function vprod (L1, L2).

load(dirac3);

Let's add a function which returns the norm of a 3-vector X.

norm3 (X) := trigsimp (  sqrt (X . X))$

 Here is our list-based implementation:

 assume the  scattering plane is z-x plane 
k_vec is directed along the +z axis and has magnitude k
kp_vec lies in the z-x plane and has magnitude kp

## Definitions of k_vec and kp_vec

k_vec : [0, 0, k]$  /* initial  photon 3-momentum */
assume ( k > 0 )$  /* so sqrt ( k^2 ) => k and not |k|  */
 
kp_vec : [kp*sin(th), 0, kp*cos(th)]$   /* final photon 3-momentum  */
assume ( kp > 0 )$

norm3 (k_vec);
norm3 (kp_vec);
k_vec . kp_vec;

## Definitions of real polarization 3-vectors ek[r] and ekp[s]

A pair of real polarization 3-vectors with the labels
ek[1]  and ek[2] are defined to be unit vectors  perpendicular to the
incident photon 3-momentum vector k_vec, so
ek[1] . k_vec  => 0,    ek[2] . k_vec  => 0, and we have the
right-hand rule cross product relation

  vprod ( ek[1], ek[2] )  =>  k_vec/k,  a unit vector along k_vec.

Let ek[1] be a unit vector directed along the positive x-axis, and
let ek[2] be a unit vector directed along the positive y-axis.

Check orthonormality of the set of two polarization 3-vectors,
and orthogonality with respect to the initial photon 3-momentum k_vec.

In addition to the package function vprod, we have the package function
Cross ( j, X, Y).

  ek[1] : [1,0,0]$

  ek[2] : [0,1,0]$
 
vprod ( ek[1], ek[2] );

Cross (3, ek[1], ek[2] );

norm3 (ek[1]);

norm3 (ek[2]);

ek[1] . k_vec;

ek[2] . k_vec;

### Definitions of vprod and Cross

vprod and Cross are defined in the Dirac3 package.

vprod (L1, L2) returns a list of the components of the cross product of
a pair of 3-vectors (each represented by a list).

Cross (j, L1, L2) returns the j'th component of L1 X L2

fundef (Cross);

fundef (vprod);

eps3[ i, j, k] is the completely anti-symmetric 3-tensor, defined in the
dirac3 package.

eps3[1,2,3];

eps3[1,3,2];

eps3[1,2,2];

Next, define a pair of unit polarization vectors ekp[1] and ekp[2], orthogonal to each other, 
and both perpendicular to the photon final 3-momenum kp_vec.

Let ekp[1] lie in the z-x scattering plane,  and let  ekp[2]  be perpendicular to the scattering
plane, and such that   ekp[1] X ekp[2] = kp_vec/kp = a unit vector in the direction of kp_vec.

 
The polarization 3-vector ekp[1] lies in the z-x scattering plane :

  ekp[1] : [cos(th), 0, -sin(th)]$
  
  norm3 (ekp[1] );
  
  ekp[1] . kp_vec;

The polarization 3-vector ekp[2]  is  perpendicular to the z-x scattering plane:

ekp[2] : [0,1,0]$
  
  norm3 (ekp[2] );
  
  ekp[2] . ekp[1];
  
  ekp[2] . kp_vec;

is (equal ( vprod (ekp[1], ekp[2]),  kp_vec/ kp) );

## Theorem 1

Theorem 1:

The following double sum of the squares of the scalar products of the four photon
polarization vectors, defined as above, ek[s] and ekp[r],
summed over r and s from 1 to 2  adds up to the expression 1 + cos(th)^2.

In the following formal (unevaluated)  definition  of Sum 1, the single quotes
prevent immediate action ( produces "noun forms").

Sum1 : 'sum ('sum ( (ek[s] . ekp[r])^2,s,1,2),r,1,2);

 Use ev (expr,  nouns) to accomplish an active evaluation of the expression expr.

The arg 'nouns' causes the evaluation of noun forms 
(typically unevaluated functions such as 'integrate or 'diff) in expr. 

 ev  ( Sum1, nouns );

 Alternatively, we could just remove the single quotes by hand:

sum (sum ( (ek[s] . ekp[r])^2,s,1,2),r,1,2);

## Theorem 2

Theorem 2

For fixed r, if we only sum over s in the above, the result is

  1 - (ku . ekp[r])^2

 where ku is a unit vector along k_vec.

ku : k_vec / k;

For either value of r, Sum2

Sum2 : 'sum ( (ek[s] . ekp[r])^2, s, 1, 2);

should be equal to:

Result : 'trigsimp ( 1 -  ( 'ku . ekp[r] )^2 );

 check case r = 1:

ev (Sum2, r = 1, nouns);

ev (Result, r = 1, nouns );

check case r = 2:

ev (Sum2, r = 2, nouns);

ev (Result, r = 2, nouns );

which establishes theorem 2.